|
| 1 | +const std = @import("std"); |
| 2 | +const Allocator = std.mem.Allocator; |
| 3 | + |
| 4 | +const spec_test_options = @import("spec_test_options"); |
| 5 | + |
| 6 | +pub fn main() !void { |
| 7 | + const allocator = std.heap.smp_allocator; |
| 8 | + const tests = &[_][]const u8{ |
| 9 | + "general", |
| 10 | + }; |
| 11 | + try write_version(); |
| 12 | + for (tests) |test_name| { |
| 13 | + try download_and_extract_spec_test( |
| 14 | + allocator, |
| 15 | + spec_test_options.spec_test_url, |
| 16 | + spec_test_options.spec_test_version, |
| 17 | + test_name, |
| 18 | + spec_test_options.spec_test_out_dir, |
| 19 | + ); |
| 20 | + } |
| 21 | +} |
| 22 | + |
| 23 | +fn write_version() !void { |
| 24 | + const version_file = try std.fs.cwd().createFile("test/spec/version.txt", .{}); |
| 25 | + defer version_file.close(); |
| 26 | + |
| 27 | + var writer = version_file.writer().any(); |
| 28 | + try writer.print( |
| 29 | + \\// This file is generated by download_spec_tests.zig. |
| 30 | + \\// This file exists as a cache key for the spec tests in CI. |
| 31 | + \\// Do not commit changes by hand. |
| 32 | + \\ |
| 33 | + \\{s} |
| 34 | + \\ |
| 35 | + , .{spec_test_options.spec_test_version}); |
| 36 | +} |
| 37 | + |
| 38 | +fn download_and_extract_spec_test( |
| 39 | + allocator: Allocator, |
| 40 | + spec_test_url: []const u8, |
| 41 | + spec_test_version: []const u8, |
| 42 | + test_name: []const u8, |
| 43 | + out_dir: []const u8, |
| 44 | +) !void { |
| 45 | + try download_spec_test_archive(allocator, spec_test_url, spec_test_version, test_name, out_dir); |
| 46 | + try extract_spec_test_archive(allocator, spec_test_version, test_name, out_dir); |
| 47 | +} |
| 48 | + |
| 49 | +fn download_spec_test_archive( |
| 50 | + allocator: Allocator, |
| 51 | + spec_test_url: []const u8, |
| 52 | + spec_test_version: []const u8, |
| 53 | + test_name: []const u8, |
| 54 | + out_dir: []const u8, |
| 55 | +) !void { |
| 56 | + const filename = try std.fmt.allocPrint(allocator, "{s}.tar.gz", .{test_name}); |
| 57 | + defer allocator.free(filename); |
| 58 | + |
| 59 | + const archive_dirname = try std.fs.path.join(allocator, &[_][]const u8{ out_dir, spec_test_version }); |
| 60 | + defer allocator.free(archive_dirname); |
| 61 | + |
| 62 | + std.fs.cwd().makePath(archive_dirname) catch {}; |
| 63 | + const archive_dir = try std.fs.cwd().openDir(archive_dirname, .{}); |
| 64 | + |
| 65 | + const already_downloaded = archive_dir.openFile(filename, .{}) catch null; |
| 66 | + if (already_downloaded != null) { |
| 67 | + std.log.info("already downloaded {s}", .{filename}); |
| 68 | + already_downloaded.?.close(); |
| 69 | + return; |
| 70 | + } |
| 71 | + |
| 72 | + var file = try archive_dir.createFile(filename, .{}); |
| 73 | + defer file.close(); |
| 74 | + |
| 75 | + std.log.info("downloading spec test {s} {s}", .{ spec_test_version, test_name }); |
| 76 | + |
| 77 | + var client: std.http.Client = .{ .allocator = allocator }; |
| 78 | + defer client.deinit(); |
| 79 | + |
| 80 | + const url = try std.fmt.allocPrint( |
| 81 | + allocator, |
| 82 | + "{s}/releases/download/{s}/{s}.tar.gz", |
| 83 | + .{ |
| 84 | + spec_test_url, |
| 85 | + spec_test_version, |
| 86 | + test_name, |
| 87 | + }, |
| 88 | + ); |
| 89 | + defer allocator.free(url); |
| 90 | + |
| 91 | + std.log.info("spec test url: {s}", .{url}); |
| 92 | + |
| 93 | + const uri = try std.Uri.parse(url); |
| 94 | + |
| 95 | + var server_header_buffer: [16 * 1024]u8 = undefined; |
| 96 | + |
| 97 | + var req = try client.open(.GET, uri, .{ |
| 98 | + .server_header_buffer = &server_header_buffer, |
| 99 | + }); |
| 100 | + defer req.deinit(); |
| 101 | + |
| 102 | + std.log.info("sending request", .{}); |
| 103 | + try req.send(); |
| 104 | + |
| 105 | + try req.wait(); |
| 106 | + |
| 107 | + // write to disk |
| 108 | + |
| 109 | + std.log.info("writing response to disk - {s}", .{filename}); |
| 110 | + |
| 111 | + var buf = try allocator.alloc(u8, 16 * 1024000); |
| 112 | + defer allocator.free(buf); |
| 113 | + var reader = req.reader(); |
| 114 | + var bytes_count: usize = 0; |
| 115 | + while (true) { |
| 116 | + const read_bytes = try reader.readAll(buf); |
| 117 | + try file.writeAll(buf[0..read_bytes]); |
| 118 | + bytes_count += read_bytes; |
| 119 | + if (read_bytes != buf.len) { |
| 120 | + break; |
| 121 | + } |
| 122 | + } |
| 123 | + std.log.info("response written to disk - {d} bytes", .{bytes_count}); |
| 124 | +} |
| 125 | + |
| 126 | +fn extract_spec_test_archive( |
| 127 | + allocator: Allocator, |
| 128 | + spec_test_version: []const u8, |
| 129 | + test_name: []const u8, |
| 130 | + out_dir: []const u8, |
| 131 | +) !void { |
| 132 | + const archive_dirname = try std.fs.path.join(allocator, &[_][]const u8{ out_dir, spec_test_version }); |
| 133 | + defer allocator.free(archive_dirname); |
| 134 | + |
| 135 | + const filename = try std.fmt.allocPrint(allocator, "{s}.tar.gz", .{test_name}); |
| 136 | + defer allocator.free(filename); |
| 137 | + |
| 138 | + const archive_dir = try std.fs.cwd().openDir(archive_dirname, .{}); |
| 139 | + |
| 140 | + const already_extracted = archive_dir.openDir(test_name, .{}) catch null; |
| 141 | + if (already_extracted != null) { |
| 142 | + std.log.info("already extracted {s}", .{filename}); |
| 143 | + return; |
| 144 | + } |
| 145 | + |
| 146 | + const archive_file = try archive_dir.openFile(filename, .{}); |
| 147 | + defer archive_file.close(); |
| 148 | + |
| 149 | + archive_dir.makeDir(test_name) catch {}; |
| 150 | + const extracted_out = try archive_dir.openDir(test_name, .{}); |
| 151 | + |
| 152 | + const file_reader = archive_file.reader(); |
| 153 | + |
| 154 | + var decompressor = std.compress.gzip.decompressor(file_reader); |
| 155 | + |
| 156 | + const gzip_reader = decompressor.reader(); |
| 157 | + |
| 158 | + std.log.info("extracting {s}", .{filename}); |
| 159 | + |
| 160 | + try std.tar.pipeToFileSystem(extracted_out, gzip_reader, .{}); |
| 161 | + std.log.info("extract {s} complete", .{filename}); |
| 162 | +} |
0 commit comments