Problem with Example SerialDelayOn.ino

[ch0zen]

Hello, thank for your library, great job
I tried some examples, they were fine

But the one most useful for me wont work
What I did:

I have a Wemos D1 mini esp 8266 board
I just uploaded the sketch SerialDelayOn.ino

And got this:

16:48:46.312 -> Delay-On finished.
16:48:46.312 -> Delay-On finished.
16:48:46.312 -> Delay-On finished.
16:48:46.358 -> Delay-On finished.
16:48:46.358 -> Delay-On finished.

and so on

This should be a line per 5 sec, right?
What can I did wrong?

Thank you
Dmitry

[MichaelUray]

If you want any action once every x seconds then I would use the cycleTrigger() function.
Also shown in the SerialCycleTrigger.ino example.

The SerialDelayOn.ino shows how to use the delayOn() function which stays permantently on when the time is elapsed as long as the input stays true.

[ch0zen]

Okay, thank you, I figured this out, this example is fine and gives the one non-blocking delay for 5 sec.

I need to implement a number of consecutive delays. Action1 - delay 100ms -- action2 -- delay 200 ms and so on
Non-blocking, of course
Can you suggest what to use, what function of the library?

Thank you!
Dm/

[MichaelUray]

Maybe try something like this:

#include <muTimer.h>

muTimer myTimer1 = muTimer();
unsigned char ucState;

void setup()
{
  Serial.begin(9600);
  Serial.println("Init done.");
  ucState = 0;
}

void loop()
{
  switch (ucState)
  {
    default:
    case 0:
      if (myTimer1.cycleTrigger(1000))
      {
        Serial.println("Cycle state 0 (1000ms) triggered.\nNext ist 2000ms.");
        ucState = 1;
      }
    
    break;

    case 1:
      if (myTimer1.cycleTrigger(2000))
      {
        Serial.println("Cycle state 1 (2000ms) triggered.\nNext ist 5000ms.");
        ucState = 2;
      }
    break;

    case 2:
      if (myTimer1.cycleTrigger(5000))
      {
        Serial.println("Cycle state 2 (5000ms) triggered.\nNext is 1000ms.");
        ucState = 0;
      }
    break;  
  }

  // The library is non-blocking.
  // Other code can get executed there in the meanwhile.
  // ...
}

[ch0zen]

oh, great!
This what I needed! SO I can use the only one myTimer1 and just change the delay in every CASE
The only thing I should not to loop this switch-case cycle, I need only one pass, how to leave the cycle in correct way?

[ch0zen]

Sorry for botheing you, I got how to get out of the cycle
Thank you for your help once again
Dmitry

[MichaelUray]

I am just curious how you solved it, I would do it like this:

#include <muTimer.h>

bool boStart;
unsigned char ucState;
muTimer myTimer1 = muTimer();

void setup()
{
  Serial.begin(9600);
  Serial.println("Init done.");
  ucState = 0;
  boStart = 1;
}

void loop()
{
  switch (ucState)
  {
    /* idle state, wait for start */
    default:
    case 0:
      if (boStart)
      {
        boStart = 0;
        myTimer1.cycleResetToOff(); /* starts timing from there */
        Serial.println("Started.");
        ucState = 1;
      }
    break;  // EDIT: I forgot this break at my first post there / did edit the post later to correct it
    
    case 1:
      if (myTimer1.cycleTrigger(1000))
      {
        Serial.println("Cycle state 1 (1000ms) triggered.\nNext ist 2000ms.");
        ucState = 2;
      }   
    break;

    case 2:
      if (myTimer1.cycleTrigger(2000))
      {
        Serial.println("Cycle state 2 (2000ms) triggered.\nNext ist 5000ms.");
        ucState = 3;
      }
    break;

    case 3:
      if (myTimer1.cycleTrigger(5000))
      {
        Serial.println("Cycle state 3 (5000ms) triggered.\nNext is 1000ms.");
        ucState = 0;
      }
    break;  
  }

  // The library is non-blocking.
  // Other code can get executed there in the meanwhile.
  // ...
}

You could also put the if (boStart)... in the last state (e.g. 4) and switch then over to state 0 if the condition gets true, it depends on your application. I propose to use the .cycleResetToOff() function to make sure that the time starts at the right moment.

[ch0zen]

Should your code stop after one pass?

[ch0zen]

Actually I need the following:
A bike with a sensor on the wheel (magnetic)
When I have 5 rotations, I should start a routine with delays once.
And wait until next 5 rotations occur. Pretty simple, but I can't get this code done ((

Can you take a look ?

void loop()
{

if (myTimer2.cycleTrigger(555)) // count++ This is a simulation of bike wheel rotation
// actually I need a debounce switch here (no problem)
{
Serial.print(" Count = "); Serial.println(count);
count++;
}

if (count == rotate_count_max) // rotate_count_max = 5
{
count = 0; // reset the count and start again
count2++; // counter2 is for distance calc and display
boStart = 1; // ??? When counter == max, I need to start the routine one time only

}  

switch (ucState)
{
/* idle state, wait for start */
default:

case 0:
  if (boStart)
  {
    boStart = 0;
    myTimer1.cycleResetToOff(); /* starts timing from there */
    Serial.println("Started.");
    ucState = 1;
  }

case 1:
  if (myTimer1.cycleTrigger(333))
  {
    Serial.println("Cycle state 1 (333ms) triggered. Next ist 555 ms.");
    ucState = 2;
  }

break;

case 2:
  if (myTimer1.cycleTrigger(555))
  {
    Serial.println("Cycle state 2 (555ms) triggered. Next ist 777 ms.");
    ucState = 3;
  }
break;

case 3:
  if (myTimer1.cycleTrigger(777))
  {
    Serial.println("Cycle state 3 (777 ms) triggered. Next is exit");
    ucState = 4;

  }
break;  

case 4:
ucState = 9; // ???
boStart = 0; // ????

break;

}

// The library is non-blocking.
// Other code can get executed there in the meanwhile.
// ...
}

[MichaelUray]

Something like this should work:

#include <muTimer.h>

// processor pin definitions
#define PIN_WHEEL_TURN_MS    3    // magnetic switch at wheel

bool boWheelTurnMsInput;
muTimer mutWheelTurnMsDebounce = muTimer();
unsigned char ucWheelCountTurn = 0;           // counts every turn
unsigned long int ulWheelCountDistance = 0;   // for distance calc and display
unsigned char rotate_count_max = 5;

bool boStart;
unsigned char ucState;
muTimer mutStateCycle = muTimer();

void setup()
{
  // configure input hardware pin with internal pull-up resistor, button has to switch against GND
  pinMode(PIN_WHEEL_TURN_MS, INPUT_PULLUP);

  // change time base from ms (default) to us
  mutWheelTurnMsDebounce.setTimeBaseToUs();

  Serial.begin(9600);
  Serial.println("Init done.");
  ucState = 0;
  boStart = 1;
}

void loop()
{

  // read input (magnetic swich) from hardware (input is inverted since internal pull-up resistor gets used), invertation depends on the hardware setup
  boWheelTurnMsInput = !digitalRead(PIN_WHEEL_TURN_MS);

  // 500 us debounce, time setting depends on application
  if (mutWheelTurnMsDebounce.delayOnOff(boWheelTurnMsInput, 500, 500))
  {
    ucWheelCountTurn++;

    // starts cycle if wheel count reaches maximum
    if (ucWheelCountTurn >= rotate_count_max)
    {
      ucWheelCountTurn = 0;
      ulWheelCountDistance++;
      boStart = 1;
    }
  }

...

[ch0zen]

Hello Michael
Thank you once again for your help

I have a working version of the sketch, but it uses delay() s. But it works. Now I have to rework it, to be able to use WiFi function and some others options, delays are not good ))

The problem is that I can't get out of the switch (ucState) cycle. I really cannot understand why
I know that I need to use this boStart = 0; if I want to get out, right?
So in the last "Case 4" I set it to =0. Anyway I got this:

0:20:56.822 -> ============= Started ==============
20:20:58.839 -> Cycle state 1 Camera ON
20:20:59.026 -> Cycle state 2 Camera OFF
20:20:59.591 -> Cycle state 3 Rover ON
20:20:59.823 -> Cycle state 4 Rover OFF
20:20:59.823 -> ============= Started ==============
20:21:01.829 -> Cycle state 1 Camera ON
20:21:02.017 -> Cycle state 2 Camera OFF
20:21:02.623 -> Cycle state 3 Rover ON
20:21:02.811 -> Cycle state 4 Rover OFF
20:21:02.811 -> ============= Started =========

So I tried to make things simple - I just uploaded your sketch
#3 (reply in thread)

• I thought it has boStart = 1; in setup, but later in the loop it switches to zero. I expected that switch (ucState) cycle should run only once, and wait until I switch the boStart = 1. But in runs continuously. Is it designed that way?

IN my case the LEDS (relays) should not be activated when the bike not in motion. The switch (ucState) should wait.?you know
Does this cycle in your code ^^^^^ run continuously on your device?

Thank you in advance

Dmitry
8266-muTimer-explore3.ino.txt

[ch0zen]

I have managed to stop and exit the cycle

All I had to do is to set the default case (just empty)
And in the last Case I had to set the ucState = 99;

Also now I had to reset the ucState to zero when the wheel counts = max
I'm still having some issues to resolve with the code, but the main problem is gone
Sorry for my poor programming skills, that's not my specialty ))

Thank you

case 4:
if (mutStateCycle.cycleTrigger(199))
{
digitalWrite(RelayPin2, 0);
Serial.println("Cycle state 4 Rover OFF");
ucState = 99;
boStart = 0;
// exit();
}
break;

default: {
// Serial.println("Stop this cycle"); delay (500);
break;
}

[ch0zen]

This delay function is not good for me, maybe I could not find the right timings?

In my magnetic switch reading task I just need a plain and simple debounce function

• the input pin is PULLED UP when idle (as you suggested too)
• when the first time the pin falls down, the trigger should be enabled
• as the delay() do, just ignore the input for, say, 200 ms.
  This would work great

In your suggested code when I push the button once, I have this in com-port monitor (attached)
log1.txt

I tried a number of settings, used ms instead of us, so far not good.

What I could did wrong?
Thank you in advance,
Dmitry

[MichaelUray]

I double checked my code and I found out that I forgot a break; at the end of case 0: in my sample code there above. I admit that I did not test it before I posted it since the change was "that easy" that nothing could go wrong. Sorry for that.
It should look like this:

  switch (ucState)
  {
    /* idle state, wait for start */
    default:
    case 0:
      if (boStart)
      {
        boStart = 0;
        mutStateCycle.cycleResetToOff(); /* starts timing from there */
        Serial.println("Started.");
        ucState = 1;
      }
      break;

    case 1:
      if (mutStateCycle.cycleTrigger(1000))
      {
        Serial.println("Cycle state 1 (1000ms) triggered.\nNext ist 2000ms.");
        ucState = 2;
      }
      break;

instead of this:

  switch (ucState)
  {
    /* idle state, wait for start */
    default:
    case 0:
      if (boStart)
      {
        boStart = 0;
        mutStateCycle.cycleResetToOff(); /* starts timing from there */
        Serial.println("Started.");
        ucState = 1;
      }
    // missing break there    

    case 1:
      if (mutStateCycle.cycleTrigger(1000))
      {
        Serial.println("Cycle state 1 (1000ms) triggered.\nNext ist 2000ms.");
        ucState = 2;
      }
      break;

Please note that I call the setTimeBaseToUs() function on the debounce instance setup, means all the time units there are in us, if you want ms, then just comment this line out.