Need help with a code!

[OleksiiMykhailov1]

I'm trying to write non-blocking code that should replace this:

boolean sequence[]={false,true,false,true,false};
void loop() {
int time1=500;
int time2=1000;
for(int i=0; i<5;i++){
if(sequence[i]){
digitalWrite(LED_PIN,HIGH);
delay(time1);
digitalWrite(LED_PIN,LOW);
}
else{delay(time2);}
}

sequence array is controlled by buttons.
I spend the last two days trying to write a non-blocking variant of this code but nothing works as is needed. In one case it was non-blocking but timings were off, in other timing was ok but blocked input from buttons and I was not able to change the array on the go.

If you can show me the direction to move from here, it will be great.
Thanks

[MichaelUray]

How about something like this:

#include <muTimer.h>

// processor pin definitions
#define LED_PIN 9

void updateSequenceInputs(void);

void setup()
{
    // configure output hardware pin
    pinMode(LED_PIN, OUTPUT);
}

int time1 = 500;
int time2 = 1000;
muTimer myTimer1 = muTimer();

boolean sequence[] = {false, true, false, true, false};
byte actualSequence = 0;

void loop()
{
    if (actualSequence >= sizeof(sequence) / sizeof(sequence[0]))
        actualSequence = 0;

    if (sequence[actualSequence])
    {
        if (myTimer1.delayOn(1, time1))
        {                           // timer elapsed
            actualSequence++;       // switch to next sequence step
            myTimer1.delayOn(0, 0); // reset timer

            digitalWrite(LED_PIN, LOW);
            updateSequenceInputs();
        }
        else
        {                           // wait for timer
            digitalWrite(LED_PIN, HIGH);
        }
    }
    else
    {
        if (myTimer1.delayOn(1, time2))
        {                           // timer elapsed
            actualSequence++;       // switch to next sequence step
            myTimer1.delayOn(0, 0); // reset timer

            digitalWrite(LED_PIN, LOW);
            updateSequenceInputs();
        }
    }
}

void updateSequenceInputs(void)
{
    // sequence[] = ....
}

I did not test it on hardware and it can get further improved by not calling digitalWrite() if the output status has not changed, but I hope it points you in the right direction.

[OleksiiMykhailov1]

Thanks a lot!