addpkg: fakehttp

Author: DeepChirp

archlinuxcn/fakehttp/PKGBUILD

@@ -0,0 +1,46 @@
+# Maintainer: DeepChirp <[email protected]>
+# Contributor: bgme <[email protected]>
+
+pkgname=fakehttp
+_reponame=FakeHTTP
+pkgver=0.9.18
+pkgrel=1
+pkgdesc="Obfuscate all your TCP connections into HTTP protocol."
+arch=('x86_64' 'armv7h' 'aarch64')
+_author=MikeWang000000
+url="https://github.com/${_author}/${_reponame}"
+license=('GPL-3.0-only')
+depends=('glibc' 'libmnl' 'libnfnetlink' 'libnetfilter_queue' 'nftables')
+makedepends=('make')
+conflicts=("${pkgname%}-git" "${pkgname%}-bin")
+install=${pkgname}.install
+source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/${pkgver}.tar.gz"
+        "${pkgname}.service"
+        "${pkgname}.sysusers"
+        "${pkgname}.conf")
+backup=("etc/conf.d/${pkgname}")
+sha256sums=('c95c4d46e122390b0dcfd8509c708a6fc6817fb3e325cb966bf81a62bae973be'
+            'cedc4c4a0018a95d071c0e16a0ba3987f7da3a5f9589e501b9b43f7572196cdd'
+            'ae55fc0399df3ed3b9585dcf3d3a43322ee555954f8f4a24796bc532e7f735b3'
+            'a316231897b13ca8a98cd7e63e83716336ec92570275fb08ddc6e53703558166')
+
+build() {
+    cd "${srcdir}/${_reponame}-${pkgver}"
+    make
+}
+
+package() {
+    install -dm755 "${pkgdir}/usr/bin"
+    install -dm755 "${pkgdir}/usr/lib/systemd/system"
+    install -dm755 "${pkgdir}/etc/conf.d"
+
+    install -Dm644 "${pkgname}.service" "${pkgdir}/usr/lib/systemd/system/"
+    install -Dm644 "${pkgname}.sysusers" "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
+    install -Dm644 "${pkgname}.conf" "${pkgdir}/etc/conf.d/${pkgname}"
+
+    cd "${srcdir}/${_reponame}-${pkgver}"
+
+    install -Dm755 build/fakehttp "${pkgdir}/usr/bin/${pkgname}"
+    install -dm755 "${pkgdir}/usr/share/doc/${pkgname}"
+    install -Dm644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
+}

archlinuxcn/fakehttp/fakehttp.conf

@@ -0,0 +1,4 @@
+# fakehttp command line args
+# Adjust according to your environment.
+# Do NOT include the "-d" option when running under systemd.
+FAKEHTTP_ARGS="-h example.com -a"

archlinuxcn/fakehttp/fakehttp.install

@@ -0,0 +1,3 @@
+post_install() {
+  echo 'Edit /etc/conf.d/fakehttp before enabling and starting the fakehttp.service'
+}

archlinuxcn/fakehttp/fakehttp.service

@@ -0,0 +1,15 @@
+[Unit]
+Description=FakeHTTP TCP obfuscation daemon
+After=network.target
+
+[Service]
+EnvironmentFile=-/etc/conf.d/fakehttp
+ExecStart=/usr/bin/fakehttp $FAKEHTTP_ARGS
+User=fakehttp
+AmbientCapabilities=CAP_NET_RAW CAP_NET_ADMIN CAP_SYS_NICE
+CapabilityBoundingSet=CAP_NET_RAW CAP_NET_ADMIN CAP_SYS_NICE
+NoNewPrivileges=yes
+Restart=on-abort
+
+[Install]
+WantedBy=multi-user.target

archlinuxcn/fakehttp/fakehttp.sysusers

@@ -0,0 +1 @@
+u fakehttp - "FakeHTTP Service" - -

archlinuxcn/fakehttp/lilac.yaml

@@ -0,0 +1,11 @@
+maintainers:
+  - github: DeepChirp
+    email: [email protected]
+
+pre_build_script: update_pkgver_and_pkgrel(_G.newver)
+post_build_script: git_pkgbuild_commit()
+
+update_on:
+  - source: github
+    github: MikeWang000000/FakeHTTP
+    use_latest_release: true