Add a test for extra_target_compatible_with

Author: jkurland-roku

tests/BUILD.bazel

@@ -14,7 +14,7 @@
 
 load("@bazel_skylib//rules:build_test.bzl", "build_test")
 load("@rules_cc//cc:defs.bzl", "cc_binary", "cc_library", "cc_test")
-load(":transitions.bzl", "dwp_file")
+load(":transitions.bzl", "dwp_file", "transition_library_to_test_define")
 
 cc_library(
     name = "stdlib",
@@ -139,3 +139,53 @@ toolchain(
     toolchain = "@@rules_foreign_cc~~tools~ninja_1.11.1_mac//:ninja_tool",
     toolchain_type = "@rules_foreign_cc//toolchains:ninja_toolchain",
 )
+
+# Testing extra_target_compatible_with
+constraint_setting(
+    name = "with_test_define",
+    default_constraint_value = ":no_test_define",
+    visibility = ["//visibility:public"],
+)
+
+constraint_value(
+    name = "no_test_define",
+    constraint_setting = ":with_test_define",
+    visibility = ["//visibility:public"],
+)
+
+constraint_value(
+    name = "yes_test_define",
+    constraint_setting = ":with_test_define",
+    visibility = ["//visibility:public"],
+)
+
+platform(
+    name = "platform_with_test_define",
+    constraint_values = [
+        ":yes_test_define",
+    ],
+    parents = ["@bazel_tools//tools:host_platform"],
+    visibility = ["//visibility:public"],
+)
+
+cc_library(
+    name = "test_define_lib",
+    srcs = ["test_define.cc"],
+)
+
+cc_test(
+    name = "test_define_no_define",
+    args = ["no"],
+    deps = [":test_define_lib"],
+)
+
+transition_library_to_test_define(
+    name = "test_define_lib_with_define",
+    lib = ":test_define_lib",
+)
+
+cc_test(
+    name = "test_define_yes_define",
+    args = ["yes"],
+    deps = [":test_define_lib_with_define"],
+)

tests/MODULE.bazel

@@ -66,10 +66,26 @@ llvm.toolchain(
     name = "llvm_toolchain",
     llvm_versions = LLVM_VERSIONS,
 )
+llvm.extra_target_compatible_with(
+    name = "llvm_toolchain",
+    constraints = ["@//:no_test_define"],
+)
 use_repo(llvm, "llvm_toolchain", "llvm_toolchain_llvm")
-
 register_toolchains("@llvm_toolchain//:all")
 
+llvm.toolchain(
+    name = "llvm_toolchain_with_define",
+    llvm_versions = LLVM_VERSIONS,
+    cxx_flags = {"": ["-DTEST_DEFINE", "-stdlib=libc++"]},
+)
+llvm.extra_target_compatible_with(
+    name = "llvm_toolchain_with_define",
+    constraints = ["//:yes_test_define"],
+)
+use_repo(llvm, "llvm_toolchain_with_define")
+register_toolchains("@llvm_toolchain_with_define//:all")
+
+
 # Example toolchain with user provided URLs.
 # TODO(siddharthab): Add test.
 llvm.toolchain(

tests/test_define.cc

@@ -0,0 +1,24 @@
+#include <string>
+#include <iostream>
+
+int main(int argc, char** argv) {
+    if (argc != 2) {
+        std::cout << "Not enough arguments" << std::endl;
+        return 1;
+    }
+
+    std::string arg = argv[1];
+
+#ifdef TEST_DEFINE
+    if (arg != "yes") {
+        std::cout << "TEST_DEFINE is defined but it was expected to be not defined" << std::endl;
+        return 1;
+    }
+#else
+    if (arg != "no") {
+        std::cout << "TEST_DEFINE is not defined but it was expected to be defined" << std::endl;
+        return 1;
+    }
+#endif
+    return 0;
+}

tests/transitions.bzl

@@ -96,3 +96,24 @@ dwp_file = rule(
         ),
     },
 )
+
+def _transition_to_test_define_impl(_, _attr):
+    return {"//command_line_option:platforms": "//:platform_with_test_define"}
+
+_transition_to_test_define = transition(
+    implementation = _transition_to_test_define_impl,
+    inputs = [],
+    outputs = ["//command_line_option:platforms"],
+)
+
+def _transition_library_to_test_define_impl(ctx):
+    return [
+        ctx.attr.lib[0][CcInfo],
+    ]
+
+transition_library_to_test_define = rule(
+    implementation = _transition_library_to_test_define_impl,
+    attrs = {
+        "lib": attr.label(cfg = _transition_to_test_define),
+    },
+)