astgrep: add a fixer

Author: mathstuf

autoload/ale/fix/registry.vim

@@ -22,6 +22,11 @@ let s:default_registry = {
 \       'suggested_filetypes': ['apkbuild'],
 \       'description': 'Fix policy violations found by apkbuild-lint in APKBUILDs',
 \   },
+\   'ast-grep': {
+\       'function': 'ale#fixers#astgrep#Fix',
+\       'suggested_filetypes': [],
+\       'description': 'Apply ast-grep rules.',
+\   },
 \   'autoimport': {
 \       'function': 'ale#fixers#autoimport#Fix',
 \       'suggested_filetypes': ['python'],

autoload/ale/fixers/astgrep.vim

@@ -0,0 +1,18 @@
+" Author: Ben Boeckel <[email protected]>
+" Description: Fix files with `ast-grep`.
+
+call ale#Set('astgrep_executable', 'ast-grep')
+call ale#Set('astgrep_scan_options', '--update-all')
+
+function! ale#fixers#astgrep#Fix(buffer) abort
+    let l:executable = ale#Var(a:buffer, 'astgrep_executable')
+    let l:options = ale#Var(a:buffer, 'astgrep_scan_options')
+
+    return {
+    \   'command': ale#Escape(l:executable)
+    \       . ' scan'
+    \       . (empty(l:options) ? '' : ' ' . l:options)
+    \       . ' %t',
+    \   'read_temporary_file': 1,
+    \}
+endfunction

doc/ale-generic.txt

@@ -38,5 +38,17 @@ g:ale_astgrep_linter_languages
   `ast-grep` linter.
 
 
+                                             *ale-options.astgrep_scan_options*
+                                                   *g:ale_astgrep_scan_options*
+                                                   *b:ale_astgrep_scan_options*
+astgrep_scan_options
+g:ale_astgrep_scan_options
+  Type: |String|
+  Default: `'--update-all'`
+
+  This variable can be modified to change the options when applying rules with
+  the `ast-grep scan` command.
+
+
 ===============================================================================
   vim:tw=78:ts=2:sts=2:sw=2:ft=help:norl:

test/fixers/test_astgrep_fixer_callback.vader

@@ -0,0 +1,27 @@
+Before:
+  Save g:ale_astgrep_executable
+  Save g:ale_astgrep_scan_options
+
+After:
+  Restore
+
+Execute(The ast-grep callback should return the correct default values):
+  AssertEqual
+  \ {
+  \   'command': ale#Escape('ast-grep') . ' scan --update-all %t',
+  \   'read_temporary_file': 1,
+  \ },
+  \ ale#fixers#astgrep#Fix(bufnr(''))
+
+Execute(The astgrep executable and options should be configurable):
+  let g:ale_astgrep_executable = '/path/to/ast-grep'
+  let g:ale_astgrep_scan_options = '--interactive'
+
+  AssertEqual
+  \ {
+  \   'command': ale#Escape('/path/to/ast-grep')
+  \     . ' scan'
+  \     . ' --interactive %t',
+  \   'read_temporary_file': 1,
+  \ },
+  \ ale#fixers#astgrep#Fix(bufnr(''))