Add support for collation in Myxql

Author: Zurga

integration_test/myxql/migrations_test.exs

@@ -29,6 +29,30 @@ defmodule Ecto.Integration.MigrationsTest do
     end
   end
 
+  text_types =  ~w/tinytext text mediumtext longtext/a
+  @text_types text_types
+
+  defmodule CollateMigration do
+    use Ecto.Migration
+
+    @text_types text_types
+    def change do
+      create table(:collate) do
+        add :string, :string, collation: "utf8mb4_bin"
+        add :varchar, :varchar, size: 255, collation: "utf8mb4_bin"
+        add :integer, :integer, collation: "utf8mb4_bin"
+
+        for type <- @text_types do
+          add type, type, collation: "utf8mb4_bin"
+        end
+      end
+
+      alter table(:collate) do
+        modify :string, :string, collation: "utf8mb4_general_ci"
+      end
+    end
+  end
+
   describe "Migrator" do
     @get_lock_command ~s[SELECT GET_LOCK('ecto_Ecto.Integration.PoolRepo', -1)]
     @release_lock_command ~s[SELECT RELEASE_LOCK('ecto_Ecto.Integration.PoolRepo')]
@@ -107,5 +131,34 @@ defmodule Ecto.Integration.MigrationsTest do
 
       assert log =~ "ALTER TABLE `alter_table` ADD `column2` varchar(255) COMMENT 'second column' AFTER `column1`"
     end
+
+    test "collation can be set on a column" do
+      num = @base_migration + System.unique_integer([:positive])
+      assert :ok = Ecto.Migrator.up(PoolRepo, num, CollateMigration, log: :info)
+      query = fn column -> """
+        SELECT collation_name
+        FROM information_schema.columns
+        WHERE table_name = 'collate' AND column_name = '#{column}';
+      """
+      end
+
+      assert %{
+        rows: [["utf8mb4_general_ci"]]
+      } = Ecto.Adapters.SQL.query!(PoolRepo, query.("string"), [])
+
+      assert %{
+        rows: [["utf8mb4_bin"]]
+      } = Ecto.Adapters.SQL.query!(PoolRepo, query.("text"), [])
+
+      for type <- @text_types do
+        assert %{
+          rows: [["utf8mb4_bin"]]
+        } = Ecto.Adapters.SQL.query!(PoolRepo, query.(to_string(type)), [])
+      end
+
+      assert %{
+        rows: [[nil]]
+      } = Ecto.Adapters.SQL.query!(PoolRepo, query.("integer"), [])
+    end
   end
 end

lib/ecto/adapters/myxql/connection.ex

@@ -1171,13 +1171,13 @@ if Code.ensure_loaded?(MyXQL) do
         quote_name(name),
         ?\s,
         reference_column_type(ref.type, opts),
-        column_options(opts),
+        column_options(ref.type, opts),
         reference_expr(ref, table, name)
       ]
     end
 
     defp column_definition(_table, {:add, name, type, opts}) do
-      [quote_name(name), ?\s, column_type(type, opts), column_options(opts)]
+      [quote_name(name), ?\s, column_type(type, opts), column_options(type, opts)]
     end
 
     defp column_changes(table, columns) do
@@ -1194,13 +1194,13 @@ if Code.ensure_loaded?(MyXQL) do
         quote_name(name),
         ?\s,
         reference_column_type(ref.type, opts),
-        column_options(opts),
+        column_options(ref.type, opts),
         constraint_expr(ref, table, name)
       ]
     end
 
     defp column_change(_table, {:add, name, type, opts}) do
-      ["ADD ", quote_name(name), ?\s, column_type(type, opts), column_options(opts)]
+      ["ADD ", quote_name(name), ?\s, column_type(type, opts), column_options(type, opts)]
     end
 
     defp column_change(table, {:add_if_not_exists, name, %Reference{} = ref, opts}) do
@@ -1209,13 +1209,19 @@ if Code.ensure_loaded?(MyXQL) do
         quote_name(name),
         ?\s,
         reference_column_type(ref.type, opts),
-        column_options(opts),
+        column_options(ref.type, opts),
         constraint_if_not_exists_expr(ref, table, name)
       ]
     end
 
     defp column_change(_table, {:add_if_not_exists, name, type, opts}) do
-      ["ADD IF NOT EXISTS ", quote_name(name), ?\s, column_type(type, opts), column_options(opts)]
+      [
+        "ADD IF NOT EXISTS ",
+        quote_name(name),
+        ?\s,
+        column_type(type, opts),
+        column_options(type, opts)
+      ]
     end
 
     defp column_change(table, {:modify, name, %Reference{} = ref, opts}) do
@@ -1225,7 +1231,7 @@ if Code.ensure_loaded?(MyXQL) do
         quote_name(name),
         ?\s,
         reference_column_type(ref.type, opts),
-        column_options(opts),
+        column_options(ref.type, opts),
         constraint_expr(ref, table, name)
       ]
     end
@@ -1237,7 +1243,7 @@ if Code.ensure_loaded?(MyXQL) do
         quote_name(name),
         ?\s,
         column_type(type, opts),
-        column_options(opts)
+        column_options(type, opts)
       ]
     end
 
@@ -1259,13 +1265,20 @@ if Code.ensure_loaded?(MyXQL) do
     defp column_change(_table, {:remove_if_exists, name}),
       do: ["DROP IF EXISTS ", quote_name(name)]
 
-    defp column_options(opts) do
+    defp column_options(type, opts) do
       default = Keyword.fetch(opts, :default)
       null = Keyword.get(opts, :null)
       after_column = Keyword.get(opts, :after)
       comment = Keyword.get(opts, :comment)
+      collation = Keyword.fetch(opts, :collation)
 
-      [default_expr(default), null_expr(null), comment_expr(comment), after_expr(after_column)]
+      [
+        default_expr(default),
+        collation(collation, type),
+        null_expr(null),
+        comment_expr(comment),
+        after_expr(after_column)
+      ]
     end
 
     defp comment_expr(comment, create_table? \\ false)
@@ -1286,6 +1299,13 @@ if Code.ensure_loaded?(MyXQL) do
     defp null_expr(true), do: " NULL"
     defp null_expr(_), do: []
 
+    defp collation({:ok, collation_name}, text_type)
+         when text_type in ~w/string char varchar text tinytext mediumtext longtext/a do
+      " COLLATE \"#{collation_name}\""
+    end
+
+    defp collation(_, _), do: []
+
     defp new_constraint_expr(%Constraint{check: check} = constraint) when is_binary(check) do
       [
         "CONSTRAINT ",