bazel: Add arch_alias repository_rule (#2945)

This allows you to use a single target for setting host_platform, and
avoids the flag complexity/duplication of having per-arch flags for
platform configuration

Signed-off-by: Ryan Northey <[email protected]>

Author: phlax

bazel/repository/BUILD

@@ -0,0 +1,65 @@
+"""Repository rule for defining a host platform based on CPU architecture.
+
+This allows you to set a single alias for multiple architectures, that resolve
+to arch-specific targets. Using `native.alias` and `select` for this doesn't work
+when using an arch as the selector.
+
+This can be useful specifically for setting the `host_platform`.
+
+Example usage:
+
+In WORKSPACE:
+
+```starlark
+arch_alias(
+    name = "clang_platform",
+    aliases = {
+        "amd64": "@envoy//bazel/platforms/rbe:rbe_linux_x64_clang_platform",
+        "aarch64": "@envoy//bazel/platforms/rbe:rbe_linux_arm64_clang_platform",
+    },
+)
+```
+And then in .bazelrc:
+
+```
+common:clang-common --host_platform=@clang_platform
+```
+
+"""
+
+ERROR_UNSUPPORTED = """
+Unsupported host architecture '{arch}'. Supported architectures are: {supported}
+"""
+
+ALIAS_BUILD = """
+alias(
+    name = "{name}",
+    actual = "{actual}",
+    visibility = ["//visibility:public"],
+)
+"""
+
+def _arch_alias_impl(ctx):
+    arch = ctx.os.arch
+    actual = ctx.attr.aliases.get(arch)
+    if not actual:
+        fail(ERROR_UNSUPPORTED.format(
+            arch = arch,
+            supported = ctx.attr.aliases.keys(),
+        ))
+    ctx.file(
+        "BUILD.bazel",
+        ALIAS_BUILD.format(
+            name = ctx.name,
+            actual = actual,
+        ),
+    )
+
+arch_alias = repository_rule(
+    implementation = _arch_alias_impl,
+    attrs = {
+        "aliases": attr.string_dict(
+            doc = "A dictionary of arch strings, mapped to associated aliases",
+        ),
+    },
+)