Using Logger with Callouts

[initdotd]

I have a simple need to use Logger, make a callout, and then perform a few more operations. Here is an example of the basic premise.

Sample
Logger.info('Simple log entry');
methodWithCallout();
Logger.info('Finished doing some work');
Logger.saveLog();

Couple of things I've tried

• Calling Logger.saveLog() prior to the callout
• Using Logger.suspendSaving(), making the callout, then Logger.resumeSaving()

The Error
When the callout occurs before any Logger methods, no error. Otherwise, you receive the typical, "You have uncommitted work pending..." exception.

Can anyone advise on how to use Logger with code that includes callouts?

[Mirco-Centrone]

You should set the saveLog() save operation as REST.

[jongpie]

@initdotd it sounds like you have other code running before you call getCoordinatesByLocation() - is that correct? Since it's a private method, I'm guessing you have a public method that first performs a DML operation, then calls getCoordinatesByLocation(). If so, then that's the issue - you can't perform any DML statements prior to making a callout.

In case it's helpful, here's a quick example class that I wrote to test this out. The method ExampleCallout.makeSomeCalloutBeforeDml() will work, and ExampleCallout.makeSomeCalloutAfterDml() will fail.

public with sharing class ExampleCallout {
    public static void makeSomeCalloutBeforeDml() {
        Logger.info('hello!');
        Logger.saveLog();

        executeCallout();

        // Running any DML statements after making a callout will succeed
        update new User(Id = UserInfo.getUserId());
    }

    public static void makeSomeCalloutAfterDml() {
        // Running any DML statements before making a callout will fail due to "You have uncommitted work pending..."'
        update new User(Id = UserInfo.getUserId());

        Logger.info('hello!');
        Logger.saveLog();

        executeCallout();
    }

    private static void executeCallout() {
        // This is just an arbitrary callout to the same org, it runs a query using the Tooling API
        // It doesn't really matter what the callout is doing, we just care that a callout is performed
        String query = 'SELECT Id, Name FROM Organization';
        String endpoint = Url.getOrgDomainUrl()?.toExternalForm() + '/services/data/v55.0/tooling/query/?q=' + query;

        HttpRequest request = new HttpRequest();
        request.setHeader('Authorization', 'Bearer ' + UserInfo.getSessionId());
        request.setHeader('Content-Type', 'application/json');
        request.setEndpoint(endpoint);
        request.setMethod('GET');

        Logger.info('Sending HTTP Request to Tooling API').setHttpRequestDetails(request);
        HttpResponse response = new Http().send(request);
        Logger.info('Received HTTP Response from Tooling API').setHttpResponseDetails(response);
    }
}

[initdotd]

Thanks @jongpie I will use your example and look for success. Meanwhile, here is my full LoggerDemo.cls for reference. Notice I'm not explicitly performing any DML.

public with sharing class LoggerDemo {

    private static final String Logger_TRANSACTION_ID = Logger.getTransactionId();

    public static void run() {

        Logger.setSaveMethod(Logger.SaveMethod.EVENT_BUS);

        // Logging on main thread using basic approach
        System.debug(Logger.getSaveMethod());
        Logger.info('START BASIC');
        Logger.error('Add log entry using Nebula Logger with logging level == ERROR');
        Logger.warn('Add log entry using Nebula Logger with logging level == WARN');
        Logger.info('Add log entry using Nebula Logger with logging level == INFO');
        Logger.debug('Add log entry using Nebula Logger with logging level == DEBUG');
        Logger.info('END BASIC');
        Logger.saveLog();

        // You may related another threads logs to the current parent by passing the transaction id
        runAsFuture(Logger_TRANSACTION_ID);

        // MAKING A CALLOUT FAILS with "You have uncomitted work pending"
        runWithCallout();
    }

    @Future
    public static void runAsFuture(String LoggerTransactionId) {
        // Use this method to associate this log to the parent log via Related Logs tab
        //Logger.setParentLogTransactionId(LoggerTransactionId);
        Logger.info('START FUTURE');
        System.debug('Using LoggerTransactionId=' + LoggerTransactionId);
        Logger.info('This log came from a different thread!');
        Logger.info('END FUTURE');
        Logger.saveLog();
    }

    private static void runWithCallout() {
        Logger.info('START CALLOUT');
        getCoordinatesByLocation(new OWGetCoordinatesByLocationRQ('Atlanta', 'GA', 'US'));
        Logger.info('END CALLOUT');
        Logger.saveLog();
    }

    // CLEAN UP SUPPORT
    public static void deleteLogs() {
        delete [SELECT Id FROM Logger__c];
    }

    // CALLOUT SUPPORT
    private static final String NAMED_CREDENTIAL = 'callout:Open_Weather';
    private static OWGetCoordinatesByLocationRS getCoordinatesByLocation(OWGetCoordinatesByLocationRQ getCoordinatesByLocationRQ) {
        Logger.info('getCoordinatesByLocation() RQ ' + getCoordinatesByLocationRQ.toQueryString());

        HttpRequest request = new HttpRequest();
        request.setMethod('GET');
        request.setEndpoint(NAMED_CREDENTIAL + '/geo/1.0/direct?' + getCoordinatesByLocationRQ.toQueryString() + '&limit=1&appid=268a68522dbf93bc050ba4ba453fb875');
        HttpResponse response = new Http().send(request);

        Logger.info('getCoordinatesByLocation() RS ' + response.getBody());
        if (response.getStatusCode() == 200) {
            String sanitizedBody = response.getBody().replace('[', '').replace(']', '');
            return (OWGetCoordinatesByLocationRS) JSON.deserialize(sanitizedBody, OWGetCoordinatesByLocationRS.class);
        }
        return null;
    }

    public with sharing class OWGetCoordinatesByLocationRQ {
        public String city { get; set; }
        public String state { get; set; }
        public String country { get; set; }

        public OWGetCoordinatesByLocationRQ(String city, String state, String country) {
            this.city = city;
            this.state = state;
            this.country = country;
        }

        public String toQueryString() {
            return String.format(
                'q={0},{1},{2}',
                new List<String>{
                    EncodingUtil.urlEncode(this.city, 'UTF-8'), EncodingUtil.urlEncode(this.state, 'UTF-8'), EncodingUtil.urlEncode(this.country, 'UTF-8')
                }
            );
        }
    }

    public with sharing class OWGetCoordinatesByLocationRS {
        public String name { get; set; }
        public Decimal lat { get; set; }
        public Decimal lon { get; set; }
        public String country { get; set; }
        public String state { get; set; }

        public OWGetCoordinatesByLocationRS() {
            this.lat = 0.0;
            this.lon = 0.0;
        }
    }
}

[jongpie]

@initdotd thanks for sharing the code! I think I was able to figure out the issue - it seems to be because you are calling your future method first, then making the callout, and the future method apparently counts as a DML statement (or at least it causes the error "You have uncommitted work pending").

If you change your code from this:

runAsFuture(Logger_TRANSACTION_ID);
runWithCallout();

to instead be like this (so the future method is called after the callout), then it works

runWithCallout();
runAsFuture(Logger_TRANSACTION_ID);

Hope this helps, but let me know if you still run into any issues.

[initdotd]

@jongpie That was it! It never occurred to me the future would behave that way, but this indeed solved the issue. I simply moved the future to the end of my primary logic method as suggested and it worked. Thank you!

[jongpie]

Wonderful, glad to hear it worked for you! Let me know if you need anything else.