nix: init flake

adding a nix flake, devshell, and formatter configuration, as partially
discussed in the discord server.

a rundown of what all this does:
- `flake.nix`: the main flake file - think of it as a project manifest
- `nix/default.nix`: a wrapper around the nixpkgs JuleC package
- `nix/shell.nix`: a shell environment for development
- `nix/formatter.nix`: treefmt configuration

Author: adamperkowski

flake.lock

@@ -0,0 +1,30 @@
+{
+  description = "Effective programming language designed to build efficient, fast, reliable and safe software while maintaining simplicity";
+
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
+  };
+
+  outputs =
+    { self, nixpkgs }:
+    let
+      systems = [
+        "x86_64-linux"
+        "aarch64-linux"
+        "i686-linux"
+        "x86_64-darwin"
+        "aarch64-darwin"
+      ];
+
+      forAllSystems = f: nixpkgs.lib.genAttrs systems (system: f nixpkgs.legacyPackages.${system});
+    in
+    {
+      packages = forAllSystems (pkgs: {
+        default = pkgs.callPackage ./nix/default.nix { };
+      });
+      devShells = forAllSystems (pkgs: {
+        default = pkgs.callPackage ./nix/shell.nix { };
+      });
+      formatter = forAllSystems (pkgs: pkgs.callPackage ./nix/formatter.nix { });
+    };
+}

flake.nix

@@ -0,0 +1,8 @@
+{
+  julec,
+}:
+
+julec.overrideAttrs (old: {
+  src = ../.;
+  passthru = {};
+})

nix/default.nix

@@ -0,0 +1,26 @@
+{ pkgs }:
+
+pkgs.treefmt.withConfig {
+  runtimeInputs = with pkgs; [
+    nixfmt-rfc-style
+    julefmt
+  ];
+
+  settings = {
+    on-unmatched = "info";
+    tree-root-file = "flake.nix";
+
+    formatter = {
+      julefmt = {
+        command = "julefmt";
+        options = [ "-w" ];
+        includes = [ "*.jule" ];
+      };
+
+      nixfmt = {
+        command = "nixfmt";
+        includes = [ "*.nix" ];
+      };
+    };
+  };
+}

nix/formatter.nix

@@ -0,0 +1,24 @@
+{ pkgs }:
+
+let
+  mainPkg = pkgs.callPackage ./default.nix { };
+  packages =
+    with pkgs;
+    [
+      clang
+      typos
+      julefmt
+    ]
+    ++ mainPkg.nativeBuildInputs;
+in
+pkgs.mkShell {
+  inherit packages;
+
+  shellHook = ''
+    echo -ne "------------------------------------\n "
+
+    echo -n "${toString (map (pkg: "• ${pkg.name}\n") packages)}"
+
+    echo "------------------------------------"
+  '';
+}