Sc3788 (#17)

* add version number to sdk

* log version on start

* linting

---------

Co-authored-by: Thomas <tfk@debian>

Author: fusionfoxy

.gitignore

@@ -1,2 +1,3 @@
 /build
 /sdk/build
+/sdk/src/signaling_device/src/version.cpp

sdk/cmake_scripts/nabto_version.cmake

@@ -0,0 +1,71 @@
+# Calculate the version from the current git repository.
+
+# This script is copied from/maintained at https://github.com/nabto/nabto-embedded-sdk
+# Script version 2020-12-08
+
+function(nabto_version version_var error_var)
+
+  find_program(GIT "git")
+  if (NOT GIT)
+    set(${error_var} "git executable not found" PARENT_SCOPE)
+    return()
+  endif()
+
+  execute_process(
+    WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
+    COMMAND git rev-parse --is-inside-work-tree
+    RESULT_VARIABLE IS_GIT_REPOSITORY)
+
+  if (NOT IS_GIT_REPOSITORY EQUAL 0)
+    set(${error_var} "directory is not a git repository" PARENT_SCOPE)
+    return()
+  endif()
+  # A git repo, generate version and put it into version_var
+
+  execute_process(
+    WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
+    COMMAND git diff --quiet --exit-code
+    RESULT_VARIABLE GIT_DIRTY)
+  execute_process(
+    WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
+    COMMAND git describe --exact-match --tags
+    OUTPUT_VARIABLE GIT_TAG ERROR_QUIET)
+  execute_process(
+    WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
+    COMMAND git rev-parse --abbrev-ref HEAD
+    OUTPUT_VARIABLE GIT_BRANCH)
+  execute_process(
+    WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
+    COMMAND git rev-list --count HEAD
+    OUTPUT_VARIABLE GIT_COUNT ERROR_QUIET)
+  execute_process(
+    WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
+    COMMAND git rev-parse --short HEAD
+    OUTPUT_VARIABLE GIT_HASH ERROR_QUIET)
+
+  if (GIT_DIRTY EQUAL 0)
+    set(GIT_DIRTY "")
+  else()
+    set(GIT_DIRTY ".dirty")
+  endif()
+
+
+  string(STRIP "${GIT_DIRTY}" GIT_DIRTY)
+  string(STRIP "${GIT_TAG}" GIT_TAG)
+  string(STRIP "${GIT_BRANCH}" GIT_BRANCH)
+  string(STRIP "${GIT_COUNT}" GIT_COUNT)
+  string(STRIP "${GIT_HASH}" GIT_HASH)
+
+  message("version.cmake variables: GIT_DIRTY ${GIT_DIRTY}, GIT_TAG ${GIT_TAG}, GIT_BRANCH ${GIT_BRANCH}, GIT_COUNT ${GIT_COUNT}, GIT_HASH: ${GIT_HASH}")
+
+  if (GIT_TAG AND NOT GIT_DIRTY)
+    # string v4.5.6 -> 4.5.6
+    string(SUBSTRING ${GIT_TAG} 1 -1 VERSION)
+  else()
+    # A feature branch
+    set(VERSION "0.0.0-branch.${GIT_BRANCH}.commits.${GIT_COUNT}+${GIT_HASH}${GIT_DIRTY}")
+  endif()
+
+  message("Generated the version: ${VERSION} based on the git repository information")
+  set(${version_var} ${VERSION} PARENT_SCOPE)
+endfunction()

sdk/cmake_scripts/version.cmake

@@ -0,0 +1,34 @@
+include("${CMAKE_CURRENT_SOURCE_DIR}/../../cmake_scripts/nabto_version.cmake")
+cmake_policy(SET CMP0007 NEW)
+
+if ("${NABTO_WEBRTC_VERSION}" STREQUAL "")
+
+  nabto_version(version_out version_error)
+
+  if (NOT version_out)
+    if (NOT EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/api/version.cpp)
+
+      message(FATAL_ERROR "No file ${CMAKE_CURRENT_SOURCE_DIR}/api/version.cpp exists and it cannot be auto generated. ${version_error}")
+    endif()
+  endif()
+else()
+  set(version_out ${NABTO_WEBRTC_VERSION})
+endif()
+
+if (version_out)
+  set(VERSION "#include <nabto/webrtc/device.hpp>\n
+#include <string>\n
+#include <array>\n
+constexpr std::array<char, 100> version_str {\"${version_out}\"};
+std::string nabto::webrtc::SignalingDevice::version() { return {std::begin(version_str),std::end(version_str)}; }\n")
+
+  if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/src/version.cpp)
+    file(READ ${CMAKE_CURRENT_SOURCE_DIR}/src/version.cpp VERSION_)
+  else()
+    set(VERSION_ "")
+  endif()
+
+  if (NOT "${VERSION}" STREQUAL "${VERSION_}")
+    file(WRITE ${CMAKE_CURRENT_SOURCE_DIR}/src/version.cpp "${VERSION}")
+  endif()
+endif()

sdk/src/signaling_device/CMakeLists.txt

@@ -1,11 +1,20 @@
 
+
+add_custom_target(GENERATE_VERSION ALL
+  WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
+  BYPRODUCTS ${CMAKE_CURRENT_SOURCE_DIR}/src/version.cpp
+  COMMAND ${CMAKE_COMMAND} -DNABTO_WEBRTC_VERSION=${NABTO_WEBRTC_VERSION} -P
+  ${CMAKE_CURRENT_SOURCE_DIR}/../../cmake_scripts/version.cmake
+  )
+
 set(src
     src/signaling_device_impl.cpp
     src/signaling_channel_impl.cpp
     src/signaling_device_factory.cpp
     src/websocket_connection.cpp
     src/signaling_error.cpp
     src/signaling.cpp
+    src/version.cpp
 )
 
 add_library(nabto_webrtc_signaling_device ${src})

sdk/src/signaling_device/include/nabto/webrtc/device.hpp

@@ -617,6 +617,13 @@ class SignalingDevice {
    * @param id The ID returned when adding the listener.
    */
   virtual void removeReconnectListener(ReconnectListenerId id) = 0;
+
+  /**
+   * Get a string representation of the Nabto WebRTC Device version.
+   *
+   * @returns String representation of the library version
+   */
+  static std::string version();
 };
 
 /**

sdk/src/signaling_device/src/signaling_device_impl.cpp

@@ -63,6 +63,7 @@ SignalingDeviceImpl::SignalingDeviceImpl(const SignalingDeviceConfig& conf)
 
 void SignalingDeviceImpl::start() {
   mutex_.lock();
+  NABTO_SIGNALING_LOGI << "Signaling Device started in version: " << version();
   if (state_ == SignalingDeviceState::NEW) {
     mutex_.unlock();
     doConnect();

sdk/test/create_destroy_signaling_device.cpp

@@ -5,4 +5,6 @@
 TEST(create_destroy, create_destroy) {
   nabto::webrtc::SignalingDeviceConfig conf;
   auto ptr = nabto::webrtc::SignalingDeviceFactory::create(conf);
+  auto version = ptr->version();
+  ASSERT_TRUE(version.size() > 0);
 }