feat(typescript): type and interface as @parameter.* (#779)

Addresses
#86 (comment)

Author: kiyoon

queries/typescript/textobjects.scm

@@ -38,3 +38,65 @@
     .
     "}"
     (#make-range! "class.inner" @_start @_end)))
+
+; type, interface items as @parameter
+; 1. parameter.inner
+(property_signature) @parameter.inner
+
+; 2. parameter.outer: Only one element, no comma
+(object_type
+  .
+  (property_signature) @parameter.outer .)
+
+(interface_body
+  .
+  (property_signature) @parameter.outer .)
+
+; 3. parameter.outer: Comma/semicolon before or after
+([
+  (object_type
+    "," @_start
+    .
+    (property_signature) @_end)
+  (interface_body
+    "," @_start
+    .
+    (property_signature) @_end)
+]
+  (#make-range! "parameter.outer" @_start @_end))
+
+([
+  (object_type
+    (property_signature) @_start
+    .
+    "," @_end)
+  (interface_body
+    (property_signature) @_start
+    .
+    "," @_end)
+]
+  (#make-range! "parameter.outer" @_start @_end))
+
+([
+  (object_type
+    ";" @_start
+    .
+    (property_signature) @_end)
+  (interface_body
+    ";" @_start
+    .
+    (property_signature) @_end)
+]
+  (#make-range! "parameter.outer" @_start @_end))
+
+([
+  (object_type
+    (property_signature) @_start
+    .
+    ";" @_end)
+  (interface_body
+    (property_signature) @_start
+    .
+    ";" @_end)
+]
+  (#make-range! "parameter.outer" @_start @_end))